CMakeLists.txt 43 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825826827828829830831832833834835836837838839840841842843844845846847848849850851852853854855856857858859860861862863864865866867868869870871872873874875876877878879880881882883884885886887888889890891892893894895896897898899900901902903904905906907908909910911912913914915916917918919920921922923924925926927928929930931932933934935936937938939940941942
  1. cmake_minimum_required(VERSION 3.0)
  2. project(open62541)
  3. # set(CMAKE_VERBOSE_MAKEFILE ON)
  4. set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/tools/cmake")
  5. find_package(PythonInterp REQUIRED)
  6. find_package(Git)
  7. include(AssignSourceGroup)
  8. include(macros)
  9. #############################
  10. # Compiled binaries folders #
  11. #############################
  12. set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  13. set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  14. set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  15. ###########
  16. # Version #
  17. ###########
  18. set(OPEN62541_VER_MAJOR 0)
  19. set(OPEN62541_VER_MINOR 4)
  20. set(OPEN62541_VER_PATCH 0)
  21. set(OPEN62541_VER_LABEL "-dev") # Appended to the X.Y.Z version format. For example "-rc1" or an empty string
  22. # If a relative path is specified, it is treated as relative to the $<INSTALL_PREFIX>
  23. set(LIB_INSTALL_DIR lib CACHE PATH "Installation path of libraries")
  24. # Set OPEN62541_VER_COMMIT
  25. if(GIT_FOUND)
  26. execute_process(COMMAND ${GIT_EXECUTABLE} describe --always --tags
  27. RESULT_VARIABLE res_var OUTPUT_VARIABLE GIT_COM_ID WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
  28. if(${res_var} EQUAL 0)
  29. string(REPLACE "\n" "" OPEN62541_VER_COMMIT ${GIT_COM_ID} )
  30. endif()
  31. endif()
  32. if(NOT OPEN62541_VER_COMMIT OR OPEN62541_VER_COMMIT STREQUAL "")
  33. set(OPEN62541_VER_COMMIT "undefined")
  34. endif()
  35. #################
  36. # Build Options #
  37. #################
  38. # Set default build type.
  39. if(NOT CMAKE_BUILD_TYPE)
  40. message(STATUS "CMAKE_BUILD_TYPE not given; setting to 'Debug'")
  41. set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Choose the type of build" FORCE)
  42. endif()
  43. option(UA_ENABLE_AMALGAMATION "Concatenate the library to a single file open62541.h/.c" OFF)
  44. set(UA_AMALGAMATION_ARCHITECUTRES "" CACHE STRING "List of architectures to include in amalgamation")
  45. mark_as_advanced(UA_AMALGAMATION_ARCHITECUTRES)
  46. # Platform. This is at the beginning in case the architecture changes some UA options
  47. set(UA_ARCHITECTURE "None" CACHE STRING "Architecture to build open62541 on")
  48. if(UA_ENABLE_AMALGAMATION)
  49. if("${UA_AMALGAMATION_ARCHITECUTRES}" STREQUAL "")
  50. # select some default architectures which should be included
  51. set(UA_AMALGAMATION_ARCHITECUTRES "win32;posix")
  52. endif()
  53. message(STATUS "Architectures included in amalgamation: ${UA_AMALGAMATION_ARCHITECUTRES}")
  54. endif()
  55. if("${UA_ARCHITECTURE}" STREQUAL "None")
  56. if(UNIX)
  57. set(UA_ARCHITECTURE "posix" CACHE STRING "" FORCE)
  58. elseif(WIN32)
  59. set(UA_ARCHITECTURE "win32" CACHE STRING "" FORCE)
  60. endif(UNIX)
  61. endif()
  62. message(STATUS "The selected architecture is: ${UA_ARCHITECTURE}")
  63. string(TOUPPER ${UA_ARCHITECTURE} UA_ARCHITECTURE_UPPER)
  64. add_definitions(-DUA_ARCHITECTURE_${UA_ARCHITECTURE_UPPER})
  65. add_subdirectory(arch)
  66. GET_PROPERTY(architectures GLOBAL PROPERTY UA_ARCHITECTURES)
  67. list(SORT architectures)
  68. set_property(CACHE UA_ARCHITECTURE PROPERTY STRINGS None ${architectures})
  69. GET_PROPERTY(ua_directories_to_include GLOBAL PROPERTY UA_INCLUDE_DIRECTORIES)
  70. include_directories(${ua_directories_to_include})
  71. GET_PROPERTY(ua_architecture_headers GLOBAL PROPERTY UA_ARCHITECTURE_HEADERS)
  72. GET_PROPERTY(ua_architecture_sources GLOBAL PROPERTY UA_ARCHITECTURE_SOURCES)
  73. set(ua_architecture_sources ${ua_architecture_sources}
  74. ${PROJECT_SOURCE_DIR}/arch/ua_network_tcp.c
  75. )
  76. set(ua_architecture_headers ${ua_architecture_headers}
  77. ${PROJECT_SOURCE_DIR}/arch/ua_network_tcp.h
  78. ${PROJECT_SOURCE_DIR}/arch/ua_architecture_functions.h
  79. )
  80. if(${UA_ARCHITECTURE} STREQUAL "None")
  81. message(FATAL_ERROR "No architecture was selected. Please select the architecture of your target platform")
  82. endif(${UA_ARCHITECTURE} STREQUAL "None")
  83. # Options
  84. set(UA_LOGLEVEL 300 CACHE STRING "Level at which logs shall be reported")
  85. option(UA_ENABLE_METHODCALLS "Enable the Method service set" ON)
  86. option(UA_ENABLE_NODEMANAGEMENT "Enable dynamic addition and removal of nodes at runtime" ON)
  87. option(UA_ENABLE_SUBSCRIPTIONS "Enable subscriptions support." ON)
  88. option(UA_ENABLE_DISCOVERY "Enable Discovery Service (LDS)" ON)
  89. option(UA_ENABLE_DISCOVERY_MULTICAST "Enable Discovery Service with multicast support (LDS-ME)" OFF)
  90. option(UA_ENABLE_COVERAGE "Enable gcov coverage" OFF)
  91. option(BUILD_SHARED_LIBS "Enable building of shared libraries (dll/so)" OFF)
  92. # Encryption Options
  93. option(UA_ENABLE_ENCRYPTION "Enable encryption support (uses mbedTLS)" OFF)
  94. if(UA_ENABLE_COVERAGE)
  95. set(CMAKE_BUILD_TYPE DEBUG)
  96. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fprofile-arcs -ftest-coverage")
  97. set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fprofile-arcs -ftest-coverage -lgcov")
  98. set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
  99. endif()
  100. if(UA_BUILD_FUZZING OR UA_BUILD_OSS_FUZZ OR UA_BUILD_FUZZING_CORPUS)
  101. # Force enable options not passed in the build script, to also fuzzy-test this code
  102. set(UA_ENABLE_DISCOVERY ON CACHE STRING "" FORCE)
  103. set(UA_ENABLE_DISCOVERY_MULTICAST ON CACHE STRING "" FORCE)
  104. set(UA_ENABLE_ENCRYPTION ON CACHE STRING "" FORCE)
  105. endif()
  106. if(UA_ENABLE_DISCOVERY_MULTICAST AND NOT UA_ENABLE_DISCOVERY)
  107. MESSAGE(WARNING "UA_ENABLE_DISCOVERY_MULTICAST is enabled, but not UA_ENABLE_DISCOVERY. UA_ENABLE_DISCOVERY_MULTICAST will be set to OFF")
  108. SET(UA_ENABLE_DISCOVERY_MULTICAST OFF CACHE BOOL "Enable Discovery Service with multicast support (LDS-ME)" FORCE)
  109. endif()
  110. # Advanced options
  111. option(UA_ENABLE_MULTITHREADING "Enable multithreading (experimental)" OFF)
  112. mark_as_advanced(UA_ENABLE_MULTITHREADING)
  113. option(UA_ENABLE_PUBSUB "Enable publish/subscribe (experimental)" OFF)
  114. mark_as_advanced(UA_ENABLE_PUBSUB)
  115. option(UA_ENABLE_STATUSCODE_DESCRIPTIONS "Enable conversion of StatusCode to human-readable error message" ON)
  116. mark_as_advanced(UA_ENABLE_STATUSCODE_DESCRIPTIONS)
  117. option(UA_ENABLE_TYPENAMES "Add the type and member names to the UA_DataType structure" ON)
  118. mark_as_advanced(UA_ENABLE_TYPENAMES)
  119. option(UA_ENABLE_DETERMINISTIC_RNG "Do not seed the random number generator (e.g. for unit tests)." OFF)
  120. mark_as_advanced(UA_ENABLE_DETERMINISTIC_RNG)
  121. option(UA_ENABLE_VALGRIND_INTERACTIVE "Enable dumping valgrind every iteration. CAUTION! SLOWDOWN!" OFF)
  122. mark_as_advanced(UA_ENABLE_VALGRIND_INTERACTIVE)
  123. option(UA_MSVC_FORCE_STATIC_CRT "Force linking with the static C-runtime library when compiling to static library with MSVC" ON)
  124. mark_as_advanced(UA_MSVC_FORCE_STATIC_CRT)
  125. option(UA_ENABLE_FULL_NS0 "Use the full NS0 instead of a minimal Namespace 0 nodeset" OFF)
  126. if (MSVC AND UA_ENABLE_FULL_NS0)
  127. # For the full NS0 we need a stack size of 8MB (as it is default on linux)
  128. # See https://github.com/open62541/open62541/issues/1326
  129. set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:8000000")
  130. endif()
  131. option(UA_FILE_NS0 "Custom NodeSet file containing NS0")
  132. mark_as_advanced(UA_FILE_NS0)
  133. # Semaphores/file system may not be available on embedded devices. It can be
  134. # disabled with the following option
  135. option(UA_ENABLE_DISCOVERY_SEMAPHORE "Enable Discovery Semaphore support" ON)
  136. mark_as_advanced(UA_ENABLE_DISCOVERY_SEMAPHORE)
  137. option(UA_ENABLE_UNIT_TESTS_MEMCHECK "Use Valgrind (Linux) or DrMemory (Windows) to detect memory leaks when running the unit tests" OFF)
  138. mark_as_advanced(UA_ENABLE_UNIT_TESTS_MEMCHECK)
  139. option(UA_ENABLE_NONSTANDARD_UDP "Enable udp extension (non-standard)" OFF)
  140. mark_as_advanced(UA_ENABLE_NONSTANDARD_UDP)
  141. option(UA_ENABLE_UNIT_TEST_FAILURE_HOOKS
  142. "Add hooks to force failure modes for additional unit tests. Not for production use!" OFF)
  143. mark_as_advanced(UA_ENABLE_UNIT_TEST_FAILURE_HOOKS)
  144. set(UA_VALGRIND_INTERACTIVE_INTERVAL 1000 CACHE STRING "The number of iterations to wait before creating the next dump")
  145. mark_as_advanced(UA_VALGRIND_INTERACTIVE_INTERVAL)
  146. # Build options for debugging
  147. option(UA_DEBUG "Enable assertions and additional functionality that should not be included in release builds" OFF)
  148. mark_as_advanced(UA_DEBUG)
  149. if(CMAKE_BUILD_TYPE STREQUAL "Debug")
  150. set(UA_DEBUG ON)
  151. endif()
  152. option(UA_DEBUG_DUMP_PKGS "Dump every package received by the server as hexdump format" OFF)
  153. mark_as_advanced(UA_DEBUG_DUMP_PKGS)
  154. # Build Targets
  155. option(UA_BUILD_EXAMPLES "Build example servers and clients" OFF)
  156. option(UA_BUILD_UNIT_TESTS "Build the unit tests" OFF)
  157. option(UA_BUILD_FUZZING "Build the fuzzing executables" OFF)
  158. mark_as_advanced(UA_BUILD_FUZZING)
  159. if(UA_BUILD_FUZZING)
  160. # oss-fuzz already defines this by default
  161. add_definitions(-DFUZZING_BUILD_MODE_UNSAFE_FOR_PRODUCTION)
  162. endif()
  163. option(UA_BUILD_FUZZING_CORPUS "Build the fuzzing corpus" OFF)
  164. mark_as_advanced(UA_BUILD_FUZZING_CORPUS)
  165. if(UA_BUILD_FUZZING_CORPUS)
  166. add_definitions(-DUA_DEBUG_DUMP_PKGS_FILE)
  167. set(UA_ENABLE_TYPENAMES ON CACHE STRING "" FORCE)
  168. set(UA_DEBUG_DUMP_PKGS ON CACHE STRING "" FORCE)
  169. endif()
  170. option(UA_BUILD_OSS_FUZZ "Special build switch used in oss-fuzz" OFF)
  171. mark_as_advanced(UA_BUILD_OSS_FUZZ)
  172. # Advanced Build Targets
  173. option(UA_BUILD_SELFSIGNED_CERTIFICATE "Generate self-signed certificate" OFF)
  174. mark_as_advanced(UA_BUILD_SELFSIGNED_CERTIFICATE)
  175. # Building shared libs (dll, so). This option is written into ua_config.h.
  176. set(UA_DYNAMIC_LINKING OFF)
  177. if(BUILD_SHARED_LIBS)
  178. set(UA_DYNAMIC_LINKING ON)
  179. if (UA_ENABLE_DISCOVERY_MULTICAST)
  180. set(MDNSD_DYNAMIC_LINKING ON)
  181. endif()
  182. endif()
  183. ######################
  184. # External Libraries #
  185. ######################
  186. list(APPEND open62541_LIBRARIES "")
  187. # Force compilation with as C++
  188. option(UA_COMPILE_AS_CXX "Force compilation with a C++ compiler" OFF)
  189. mark_as_advanced(UA_COMPILE_AS_CXX)
  190. if (UA_COMPILE_AS_CXX)
  191. # We need the UINT32_C define
  192. add_definitions(-D__STDC_CONSTANT_MACROS)
  193. endif()
  194. if(UA_ENABLE_ENCRYPTION)
  195. # The recommended way is to install mbedtls via the OS package manager. If
  196. # that is not possible, manually compile mbedTLS and set the cmake variables
  197. # defined in /tools/cmake/FindMbedTLS.cmake.
  198. find_package(MbedTLS REQUIRED)
  199. list(APPEND open62541_LIBRARIES ${MBEDTLS_LIBRARIES})
  200. endif()
  201. if(NOT WIN32)
  202. if(QNXNTO)
  203. list(APPEND open62541_LIBRARIES socket)
  204. list(APPEND open62541_LIBRARIES c)
  205. list(APPEND open62541_LIBRARIES stdc++)
  206. else()
  207. list(APPEND open62541_LIBRARIES m)
  208. if(UA_ENABLE_MULTITHREADING OR UA_BUILD_UNIT_TESTS)
  209. list(APPEND open62541_LIBRARIES pthread)
  210. endif()
  211. if(NOT APPLE AND (NOT ${CMAKE_SYSTEM_NAME} MATCHES "OpenBSD"))
  212. list(APPEND open62541_LIBRARIES rt)
  213. endif()
  214. endif()
  215. else()
  216. list(APPEND open62541_LIBRARIES ws2_32)
  217. if(UA_ENABLE_DISCOVERY_MULTICAST OR UA_ENABLE_PUBSUB)
  218. list(APPEND open62541_LIBRARIES iphlpapi)
  219. endif()
  220. endif()
  221. #####################
  222. # Compiler Settings #
  223. #####################
  224. if(NOT UA_COMPILE_AS_CXX AND (CMAKE_COMPILER_IS_GNUCC OR "x${CMAKE_C_COMPILER_ID}" STREQUAL "xClang"))
  225. # Compiler
  226. add_definitions(-std=c99 -pipe
  227. -Wall -Wextra -Werror -Wpedantic
  228. -Wno-static-in-inline # clang doesn't like the use of static inline methods inside static inline methods
  229. -Wno-overlength-strings # may happen in the nodeset compiler when complex values are directly encoded
  230. -Wno-unused-parameter # some methods may require unused arguments to cast to a method pointer
  231. -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls
  232. -Wformat -Wformat-security -Wformat-nonliteral
  233. -Wuninitialized -Winit-self
  234. -Wcast-qual
  235. -Wstrict-overflow
  236. -Wnested-externs
  237. -Wmultichar
  238. -Wundef
  239. -Wc++-compat)
  240. if(NOT WIN32 AND NOT CYGWIN AND NOT QNXNTO AND (NOT ${CMAKE_SYSTEM_NAME} MATCHES "OpenBSD"))
  241. add_definitions(-Wshadow -Wconversion -fvisibility=hidden -fPIC)
  242. endif()
  243. if(UA_ENABLE_AMALGAMATION)
  244. add_definitions(-Wno-unused-function)
  245. endif()
  246. # Linker
  247. set(CMAKE_SHARED_LIBRARY_LINK_C_FLAGS "") # cmake sets -rdynamic by default
  248. # Debug
  249. if(CMAKE_BUILD_TYPE STREQUAL "Debug")
  250. # add_definitions(-fsanitize=address)
  251. # list(APPEND open62541_LIBRARIES asan)
  252. # add_definitions(-fsanitize=undefined)
  253. # list(APPEND open62541_LIBRARIES ubsan)
  254. endif()
  255. # Strip release builds
  256. if(CMAKE_BUILD_TYPE STREQUAL "MinSizeRel" OR CMAKE_BUILD_TYPE STREQUAL "Release")
  257. add_definitions(-ffunction-sections -fdata-sections -fno-stack-protector -fno-unwind-tables
  258. -fno-asynchronous-unwind-tables -fno-math-errno -fmerge-all-constants -fno-ident)
  259. set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -s")
  260. set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -s")
  261. if(APPLE)
  262. set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -Wl,-dead_strip")
  263. set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-dead_strip")
  264. else()
  265. set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -Wl,--gc-sections")
  266. set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--gc-sections")
  267. endif()
  268. if(NOT WIN32 AND NOT CYGWIN AND NOT APPLE)
  269. # these settings reduce the binary size by ~2kb
  270. set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -Wl,-z,norelro -Wl,--hash-style=gnu -Wl,--build-id=none")
  271. endif()
  272. endif()
  273. endif()
  274. if(APPLE)
  275. set(CMAKE_MACOSX_RPATH 1)
  276. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_DARWIN_C_SOURCE=1")
  277. endif()
  278. if(MSVC)
  279. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W3 /WX /w44996") # Compiler warnings, error on warning
  280. if(UA_MSVC_FORCE_STATIC_CRT AND NOT BUILD_SHARED_LIBS)
  281. set(CompilerFlags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_C_FLAGS
  282. CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE)
  283. foreach(CompilerFlag ${CompilerFlags})
  284. string(REPLACE "/MD" "/MT" ${CompilerFlag} "${${CompilerFlag}}")
  285. endforeach()
  286. endif()
  287. endif()
  288. #########################
  289. # Generate Main Library #
  290. #########################
  291. file(MAKE_DIRECTORY "${PROJECT_BINARY_DIR}/src_generated")
  292. configure_file("include/ua_config.h.in" "${PROJECT_BINARY_DIR}/src_generated/ua_config.h")
  293. configure_file("include/open62541.pc.in" "${PROJECT_BINARY_DIR}/src_generated/open62541.pc" @ONLY)
  294. if(UA_ENABLE_DISCOVERY_MULTICAST)
  295. set(MDNSD_LOGLEVEL 300 CACHE STRING "Level at which logs shall be reported" FORCE)
  296. configure_file("deps/mdnsd/libmdnsd/mdnsd_config.h.in" "${PROJECT_BINARY_DIR}/src_generated/mdnsd_config.h")
  297. endif()
  298. if(UA_ENABLE_DISCOVERY)
  299. include_directories(${PROJECT_SOURCE_DIR}/src/client)
  300. endif()
  301. include_directories(${PROJECT_SOURCE_DIR}/include
  302. ${PROJECT_SOURCE_DIR}/plugins
  303. ${PROJECT_SOURCE_DIR}/deps
  304. ${PROJECT_SOURCE_DIR}/src/pubsub
  305. ${PROJECT_BINARY_DIR}
  306. ${PROJECT_BINARY_DIR}/src_generated
  307. ${MBEDTLS_INCLUDE_DIRS})
  308. if(NOT "${UA_AMALGAMATION_ARCHITECUTRES}" STREQUAL "")
  309. set(exported_headers)
  310. foreach(arch ${UA_AMALGAMATION_ARCHITECUTRES})
  311. list(APPEND exported_headers ${PROJECT_SOURCE_DIR}/arch/${arch}/ua_architecture.h)
  312. endforeach()
  313. else()
  314. set(exported_headers ${PROJECT_SOURCE_DIR}/arch/${UA_ARCHITECTURE}/ua_architecture.h)
  315. endif()
  316. set(exported_headers ${exported_headers}
  317. ${PROJECT_BINARY_DIR}/src_generated/ua_config.h
  318. ${PROJECT_SOURCE_DIR}/deps/ms_stdint.h
  319. ${PROJECT_BINARY_DIR}/src_generated/ua_statuscodes.h
  320. ${PROJECT_BINARY_DIR}/src_generated/ua_nodeids.h
  321. ${PROJECT_SOURCE_DIR}/include/ua_constants.h
  322. ${PROJECT_SOURCE_DIR}/include/ua_types.h
  323. ${PROJECT_BINARY_DIR}/src_generated/ua_types_generated.h
  324. ${PROJECT_BINARY_DIR}/src_generated/ua_types_generated_handling.h
  325. ${PROJECT_SOURCE_DIR}/include/ua_server.h
  326. ${PROJECT_SOURCE_DIR}/include/ua_plugin_log.h
  327. ${PROJECT_SOURCE_DIR}/include/ua_plugin_network.h
  328. ${PROJECT_SOURCE_DIR}/include/ua_plugin_access_control.h
  329. ${PROJECT_SOURCE_DIR}/include/ua_plugin_pki.h
  330. ${PROJECT_SOURCE_DIR}/include/ua_plugin_securitypolicy.h
  331. ${PROJECT_SOURCE_DIR}/include/ua_server_pubsub.h
  332. ${PROJECT_SOURCE_DIR}/include/ua_plugin_pubsub.h
  333. ${PROJECT_SOURCE_DIR}/include/ua_plugin_nodestore.h
  334. ${PROJECT_SOURCE_DIR}/include/ua_server_config.h
  335. ${PROJECT_SOURCE_DIR}/include/ua_client_config.h
  336. ${PROJECT_SOURCE_DIR}/include/ua_client.h
  337. ${PROJECT_SOURCE_DIR}/include/ua_client_highlevel.h
  338. ${PROJECT_SOURCE_DIR}/include/ua_client_subscriptions.h)
  339. set(internal_headers ${PROJECT_SOURCE_DIR}/deps/queue.h
  340. ${PROJECT_SOURCE_DIR}/deps/pcg_basic.h
  341. ${PROJECT_SOURCE_DIR}/deps/libc_time.h
  342. ${PROJECT_SOURCE_DIR}/src/ua_util.h
  343. ${PROJECT_SOURCE_DIR}/src/ua_types_encoding_binary.h
  344. ${PROJECT_BINARY_DIR}/src_generated/ua_types_generated_encoding_binary.h
  345. ${PROJECT_BINARY_DIR}/src_generated/ua_transport_generated.h
  346. ${PROJECT_BINARY_DIR}/src_generated/ua_transport_generated_handling.h
  347. ${PROJECT_BINARY_DIR}/src_generated/ua_transport_generated_encoding_binary.h
  348. ${PROJECT_SOURCE_DIR}/src/ua_connection_internal.h
  349. ${PROJECT_SOURCE_DIR}/src/ua_securechannel.h
  350. ${PROJECT_SOURCE_DIR}/src/ua_timer.h
  351. ${PROJECT_SOURCE_DIR}/src/server/ua_session.h
  352. ${PROJECT_SOURCE_DIR}/src/server/ua_subscription.h
  353. ${PROJECT_SOURCE_DIR}/src/server/ua_session_manager.h
  354. ${PROJECT_SOURCE_DIR}/src/server/ua_securechannel_manager.h
  355. ${PROJECT_SOURCE_DIR}/src/server/ua_server_internal.h
  356. ${PROJECT_SOURCE_DIR}/src/server/ua_services.h
  357. ${PROJECT_BINARY_DIR}/src_generated/ua_namespace0.h
  358. ${PROJECT_SOURCE_DIR}/src/client/ua_client_internal.h)
  359. # TODO: make client optional
  360. set(lib_sources ${PROJECT_SOURCE_DIR}/src/ua_types.c
  361. ${PROJECT_SOURCE_DIR}/src/ua_types_encoding_binary.c
  362. ${PROJECT_BINARY_DIR}/src_generated/ua_types_generated.c
  363. ${PROJECT_BINARY_DIR}/src_generated/ua_transport_generated.c
  364. ${PROJECT_BINARY_DIR}/src_generated/ua_statuscodes.c
  365. ${PROJECT_SOURCE_DIR}/src/ua_util.c
  366. ${PROJECT_SOURCE_DIR}/src/ua_timer.c
  367. ${PROJECT_SOURCE_DIR}/src/ua_connection.c
  368. ${PROJECT_SOURCE_DIR}/src/ua_securechannel.c
  369. ${PROJECT_SOURCE_DIR}/src/server/ua_session.c
  370. ${PROJECT_SOURCE_DIR}/src/server/ua_nodes.c
  371. ${PROJECT_SOURCE_DIR}/src/server/ua_server.c
  372. ${PROJECT_SOURCE_DIR}/src/server/ua_server_ns0.c
  373. ${PROJECT_BINARY_DIR}/src_generated/ua_namespace0.c
  374. ${PROJECT_SOURCE_DIR}/src/server/ua_server_binary.c
  375. ${PROJECT_SOURCE_DIR}/src/server/ua_server_utils.c
  376. ${PROJECT_SOURCE_DIR}/src/server/ua_server_worker.c
  377. ${PROJECT_SOURCE_DIR}/src/server/ua_server_discovery.c
  378. ${PROJECT_SOURCE_DIR}/src/server/ua_securechannel_manager.c
  379. ${PROJECT_SOURCE_DIR}/src/server/ua_session_manager.c
  380. ${PROJECT_SOURCE_DIR}/src/server/ua_subscription.c
  381. ${PROJECT_SOURCE_DIR}/src/server/ua_subscription_datachange.c
  382. # services
  383. ${PROJECT_SOURCE_DIR}/src/server/ua_services_view.c
  384. ${PROJECT_SOURCE_DIR}/src/server/ua_services_call.c
  385. ${PROJECT_SOURCE_DIR}/src/server/ua_services_session.c
  386. ${PROJECT_SOURCE_DIR}/src/server/ua_services_attribute.c
  387. ${PROJECT_SOURCE_DIR}/src/server/ua_services_discovery.c
  388. ${PROJECT_SOURCE_DIR}/src/server/ua_services_subscription.c
  389. ${PROJECT_SOURCE_DIR}/src/server/ua_services_securechannel.c
  390. ${PROJECT_SOURCE_DIR}/src/server/ua_services_nodemanagement.c
  391. ${PROJECT_SOURCE_DIR}/src/server/ua_services_discovery_multicast.c
  392. # client
  393. ${PROJECT_SOURCE_DIR}/src/client/ua_client.c
  394. ${PROJECT_SOURCE_DIR}/src/client/ua_client_connect.c
  395. ${PROJECT_SOURCE_DIR}/src/client/ua_client_discovery.c
  396. ${PROJECT_SOURCE_DIR}/src/client/ua_client_highlevel.c
  397. ${PROJECT_SOURCE_DIR}/src/client/ua_client_subscriptions.c
  398. # dependencies
  399. ${PROJECT_SOURCE_DIR}/deps/libc_time.c
  400. ${PROJECT_SOURCE_DIR}/deps/pcg_basic.c)
  401. set(default_plugin_headers ${PROJECT_SOURCE_DIR}/plugins/ua_accesscontrol_default.h
  402. ${PROJECT_SOURCE_DIR}/plugins/ua_pki_certificate.h
  403. ${PROJECT_SOURCE_DIR}/plugins/ua_log_stdout.h
  404. ${PROJECT_SOURCE_DIR}/plugins/ua_nodestore_default.h
  405. ${PROJECT_SOURCE_DIR}/plugins/ua_config_default.h
  406. ${PROJECT_SOURCE_DIR}/plugins/ua_securitypolicy_none.h
  407. )
  408. set(default_plugin_sources ${PROJECT_SOURCE_DIR}/plugins/ua_log_stdout.c
  409. ${PROJECT_SOURCE_DIR}/plugins/ua_accesscontrol_default.c
  410. ${PROJECT_SOURCE_DIR}/plugins/ua_pki_certificate.c
  411. ${PROJECT_SOURCE_DIR}/plugins/ua_nodestore_default.c
  412. ${PROJECT_SOURCE_DIR}/plugins/ua_config_default.c
  413. ${PROJECT_SOURCE_DIR}/plugins/ua_securitypolicy_none.c
  414. )
  415. if(UA_ENABLE_ENCRYPTION)
  416. list(APPEND default_plugin_headers ${PROJECT_SOURCE_DIR}/plugins/ua_securitypolicy_basic128rsa15.h
  417. ${PROJECT_SOURCE_DIR}/plugins/ua_securitypolicy_basic256sha256.h)
  418. list(APPEND default_plugin_sources ${PROJECT_SOURCE_DIR}/plugins/ua_securitypolicy_basic128rsa15.c
  419. ${PROJECT_SOURCE_DIR}/plugins/ua_securitypolicy_basic256sha256.c)
  420. endif()
  421. if(UA_ENABLE_PUBSUB)
  422. list(APPEND internal_headers ${PROJECT_SOURCE_DIR}/src/pubsub/ua_pubsub_networkmessage.h
  423. ${PROJECT_SOURCE_DIR}/src/pubsub/ua_pubsub_manager.h)
  424. list(APPEND lib_sources ${PROJECT_SOURCE_DIR}/src/pubsub/ua_pubsub_networkmessage.c
  425. ${PROJECT_SOURCE_DIR}/src/pubsub/ua_pubsub.c
  426. ${PROJECT_SOURCE_DIR}/src/pubsub/ua_pubsub_manager.c)
  427. list(APPEND default_plugin_headers ${PROJECT_SOURCE_DIR}/plugins/ua_network_pubsub_udp.h)
  428. list(APPEND default_plugin_sources ${PROJECT_SOURCE_DIR}/plugins/ua_network_pubsub_udp.c)
  429. endif()
  430. if(UA_DEBUG_DUMP_PKGS)
  431. list(APPEND lib_sources ${PROJECT_SOURCE_DIR}/plugins/ua_debug_dump_pkgs.c)
  432. endif()
  433. if(UA_ENABLE_NONSTANDARD_UDP)
  434. list(APPEND exported_headers ${PROJECT_SOURCE_DIR}/arch/ua_network_udp.h)
  435. endif()
  436. if(UA_ENABLE_DISCOVERY_MULTICAST)
  437. # prepend in list, otherwise it complains that winsock2.h has to be included before windows.h
  438. set(internal_headers ${PROJECT_BINARY_DIR}/src_generated/mdnsd_config.h
  439. ${PROJECT_SOURCE_DIR}/deps/mdnsd/libmdnsd/1035.h
  440. ${PROJECT_SOURCE_DIR}/deps/mdnsd/libmdnsd/xht.h
  441. ${PROJECT_SOURCE_DIR}/deps/mdnsd/libmdnsd/sdtxt.h
  442. ${PROJECT_SOURCE_DIR}/deps/mdnsd/libmdnsd/mdnsd.h
  443. ${internal_headers} )
  444. list(APPEND internal_headers ${PROJECT_SOURCE_DIR}/src/server/ua_mdns_internal.h)
  445. set(lib_sources ${PROJECT_SOURCE_DIR}/src/server/ua_mdns.c
  446. ${PROJECT_SOURCE_DIR}/deps/mdnsd/libmdnsd/1035.c
  447. ${PROJECT_SOURCE_DIR}/deps/mdnsd/libmdnsd/xht.c
  448. ${PROJECT_SOURCE_DIR}/deps/mdnsd/libmdnsd/sdtxt.c
  449. ${PROJECT_SOURCE_DIR}/deps/mdnsd/libmdnsd/mdnsd.c
  450. ${lib_sources})
  451. endif()
  452. #########################
  453. # Generate source files #
  454. #########################
  455. if (UA_ENABLE_FULL_NS0)
  456. if(NOT UA_FILE_NS0)
  457. set(UA_FILE_NS0 ${PROJECT_SOURCE_DIR}/deps/ua-nodeset/Schema/Opc.Ua.NodeSet2.xml)
  458. endif()
  459. set(UA_FILE_DATATYPES "")
  460. set(UA_FILE_NODEIDS ${PROJECT_SOURCE_DIR}/deps/ua-nodeset/Schema/NodeIds.csv)
  461. set(UA_FILE_STATUSCODES ${PROJECT_SOURCE_DIR}/deps/ua-nodeset/Schema/StatusCode.csv)
  462. set(UA_FILE_TYPES_BSD ${PROJECT_SOURCE_DIR}/deps/ua-nodeset/Schema/Opc.Ua.Types.bsd)
  463. else()
  464. if(NOT UA_FILE_NS0)
  465. set(UA_FILE_NS0 ${PROJECT_SOURCE_DIR}/tools/schema/Opc.Ua.NodeSet2.Minimal.xml)
  466. endif()
  467. set(UA_FILE_DATATYPES "${PROJECT_SOURCE_DIR}/tools/schema/datatypes_minimal.txt")
  468. set(UA_FILE_NODEIDS ${PROJECT_SOURCE_DIR}/tools/schema/NodeIds.csv)
  469. set(UA_FILE_STATUSCODES ${PROJECT_SOURCE_DIR}/tools/schema/StatusCode.csv)
  470. set(UA_FILE_TYPES_BSD ${PROJECT_SOURCE_DIR}/tools/schema/Opc.Ua.Types.bsd)
  471. endif()
  472. if(NOT EXISTS "${UA_FILE_NS0}")
  473. message(FATAL_ERROR "File ${UA_FILE_NS0} not found. You probably need to initialize the git submodule for deps/ua-nodeset.")
  474. endif()
  475. if (UA_FILE_DATATYPES STREQUAL "")
  476. set(SELECTED_TYPES_TMP "")
  477. else()
  478. set(SELECTED_TYPES_TMP "--selected-types=${UA_FILE_DATATYPES}")
  479. endif()
  480. # standard-defined data types
  481. add_custom_command(OUTPUT ${PROJECT_BINARY_DIR}/src_generated/ua_types_generated.c
  482. ${PROJECT_BINARY_DIR}/src_generated/ua_types_generated.h
  483. ${PROJECT_BINARY_DIR}/src_generated/ua_types_generated_handling.h
  484. ${PROJECT_BINARY_DIR}/src_generated/ua_types_generated_encoding_binary.h
  485. PRE_BUILD
  486. COMMAND ${PYTHON_EXECUTABLE} ${PROJECT_SOURCE_DIR}/tools/generate_datatypes.py
  487. --type-csv=${UA_FILE_NODEIDS}
  488. ${SELECTED_TYPES_TMP}
  489. --type-bsd=${UA_FILE_TYPES_BSD}
  490. ${PROJECT_BINARY_DIR}/src_generated/ua_types
  491. DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tools/generate_datatypes.py
  492. ${UA_FILE_NODEIDS}
  493. ${UA_FILE_TYPES_BSD}
  494. ${UA_FILE_DATATYPES})
  495. # we need a custom target to avoid that the generator is called concurrently and thus overwriting files while the other thread is compiling
  496. add_custom_target(open62541-generator-types DEPENDS
  497. ${PROJECT_BINARY_DIR}/src_generated/ua_types_generated.c
  498. ${PROJECT_BINARY_DIR}/src_generated/ua_types_generated.h
  499. ${PROJECT_BINARY_DIR}/src_generated/ua_types_generated_handling.h
  500. ${PROJECT_BINARY_DIR}/src_generated/ua_types_generated_encoding_binary.h)
  501. # transport data types
  502. add_custom_command(OUTPUT ${PROJECT_BINARY_DIR}/src_generated/ua_transport_generated.c
  503. ${PROJECT_BINARY_DIR}/src_generated/ua_transport_generated.h
  504. ${PROJECT_BINARY_DIR}/src_generated/ua_transport_generated_handling.h
  505. ${PROJECT_BINARY_DIR}/src_generated/ua_transport_generated_encoding_binary.h
  506. PRE_BUILD
  507. COMMAND ${PYTHON_EXECUTABLE} ${PROJECT_SOURCE_DIR}/tools/generate_datatypes.py
  508. --namespace=1
  509. --selected-types=${PROJECT_SOURCE_DIR}/tools/schema/datatypes_transport.txt
  510. --type-bsd=${UA_FILE_TYPES_BSD}
  511. --type-bsd=${PROJECT_SOURCE_DIR}/tools/schema/Custom.Opc.Ua.Transport.bsd
  512. --no-builtin
  513. ${PROJECT_BINARY_DIR}/src_generated/ua_transport
  514. DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tools/generate_datatypes.py
  515. ${PROJECT_SOURCE_DIR}/tools/schema/datatypes_transport.txt
  516. ${UA_FILE_TYPES_BSD}
  517. ${PROJECT_SOURCE_DIR}/tools/schema/Custom.Opc.Ua.Transport.bsd)
  518. # we need a custom target to avoid that the generator is called concurrently and thus overwriting files while the other thread is compiling
  519. add_custom_target(open62541-generator-transport DEPENDS
  520. ${PROJECT_BINARY_DIR}/src_generated/ua_transport_generated.c
  521. ${PROJECT_BINARY_DIR}/src_generated/ua_transport_generated.h
  522. ${PROJECT_BINARY_DIR}/src_generated/ua_transport_generated_handling.h
  523. ${PROJECT_BINARY_DIR}/src_generated/ua_transport_generated_encoding_binary.h)
  524. # statuscode explanation
  525. add_custom_command(OUTPUT ${PROJECT_BINARY_DIR}/src_generated/ua_statuscodes.h
  526. ${PROJECT_BINARY_DIR}/src_generated/ua_statuscodes.c
  527. PRE_BUILD
  528. COMMAND ${PYTHON_EXECUTABLE} ${PROJECT_SOURCE_DIR}/tools/generate_statuscode_descriptions.py
  529. ${UA_FILE_STATUSCODES} ${PROJECT_BINARY_DIR}/src_generated/ua_statuscodes
  530. DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tools/generate_statuscode_descriptions.py
  531. ${UA_FILE_STATUSCODES})
  532. # nodeid explanation
  533. add_custom_command(OUTPUT ${PROJECT_BINARY_DIR}/src_generated/ua_nodeids.h
  534. PRE_BUILD
  535. COMMAND ${PYTHON_EXECUTABLE} ${PROJECT_SOURCE_DIR}/tools/generate_nodeid_descriptions.py
  536. ${UA_FILE_NODEIDS} ${PROJECT_BINARY_DIR}/src_generated/ua_nodeids
  537. DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tools/generate_nodeid_descriptions.py
  538. ${UA_FILE_NODEIDS})
  539. # we need a custom target to avoid that the generator is called concurrently and
  540. # thus overwriting files while the other thread is compiling
  541. add_custom_target(open62541-generator-statuscode DEPENDS
  542. ${PROJECT_BINARY_DIR}/src_generated/ua_nodeids.h
  543. ${PROJECT_BINARY_DIR}/src_generated/ua_statuscodes.h
  544. ${PROJECT_BINARY_DIR}/src_generated/ua_statuscodes.c)
  545. # single-file release
  546. add_custom_command(OUTPUT ${PROJECT_BINARY_DIR}/open62541.h
  547. PRE_BUILD
  548. COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/tools/amalgamate.py
  549. ${OPEN62541_VER_COMMIT} ${CMAKE_CURRENT_BINARY_DIR}/open62541.h
  550. ${exported_headers} ${default_plugin_headers} ${ua_architecture_headers}
  551. DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tools/amalgamate.py
  552. ${exported_headers} ${default_plugin_headers} ${ua_architecture_headers})
  553. add_custom_command(OUTPUT ${PROJECT_BINARY_DIR}/open62541.c
  554. PRE_BUILD
  555. COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/tools/amalgamate.py
  556. ${OPEN62541_VER_COMMIT} ${CMAKE_CURRENT_BINARY_DIR}/open62541.c
  557. ${internal_headers} ${lib_sources} ${default_plugin_sources} ${ua_architecture_sources}
  558. DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tools/amalgamate.py ${internal_headers}
  559. ${lib_sources} ${default_plugin_sources} ${ua_architecture_sources} )
  560. add_custom_target(open62541-amalgamation-source DEPENDS ${PROJECT_BINARY_DIR}/open62541.c)
  561. add_custom_target(open62541-amalgamation-header DEPENDS ${PROJECT_BINARY_DIR}/open62541.h)
  562. add_dependencies(open62541-amalgamation-header open62541-generator-types)
  563. add_dependencies(open62541-amalgamation-source open62541-generator-types
  564. open62541-generator-transport open62541-generator-statuscode)
  565. set(NODESET_MAX_STR_LEN 0)
  566. if(MSVC)
  567. # Visual Studio has a maximum string length of 65535 bytes
  568. set(NODESET_MAX_STR_LEN 65535)
  569. endif()
  570. # generated namespace 0
  571. add_custom_command(OUTPUT ${PROJECT_BINARY_DIR}/src_generated/ua_namespace0.c
  572. ${PROJECT_BINARY_DIR}/src_generated/ua_namespace0.h
  573. PRE_BUILD
  574. COMMAND ${PYTHON_EXECUTABLE} ${PROJECT_SOURCE_DIR}/tools/nodeset_compiler/nodeset_compiler.py
  575. --generate-ns0
  576. --internal-headers
  577. --max-string-length=${NODESET_MAX_STR_LEN}
  578. --ignore ${PROJECT_SOURCE_DIR}/tools/nodeset_compiler/NodeID_NS0_Base.txt
  579. --xml ${UA_FILE_NS0}
  580. ${PROJECT_BINARY_DIR}/src_generated/ua_namespace0
  581. DEPENDS ${UA_FILE_NS0}
  582. ${PROJECT_SOURCE_DIR}/tools/nodeset_compiler/nodeset_compiler.py
  583. ${PROJECT_SOURCE_DIR}/tools/nodeset_compiler/nodes.py
  584. ${PROJECT_SOURCE_DIR}/tools/nodeset_compiler/nodeset.py
  585. ${PROJECT_SOURCE_DIR}/tools/nodeset_compiler/datatypes.py
  586. ${PROJECT_SOURCE_DIR}/tools/nodeset_compiler/backend_open62541.py
  587. ${PROJECT_SOURCE_DIR}/tools/nodeset_compiler/backend_open62541_nodes.py
  588. ${PROJECT_SOURCE_DIR}/tools/nodeset_compiler/backend_open62541_datatypes.py)
  589. # stack protector needs to be disabled for the huge ns0 file, otherwise it may take many minutes to compile the file.
  590. if(NOT MSVC)
  591. set_source_files_properties(${PROJECT_BINARY_DIR}/src_generated/ua_namespace0.c PROPERTIES COMPILE_FLAGS -fno-stack-protector)
  592. endif()
  593. # we need a custom target to avoid that the generator is called concurrently and thus overwriting files while the other thread is compiling
  594. add_custom_target(open62541-generator-namespace DEPENDS
  595. ${PROJECT_BINARY_DIR}/src_generated/ua_namespace0.c
  596. ${PROJECT_BINARY_DIR}/src_generated/ua_namespace0.h)
  597. #####################
  598. # Build the Library #
  599. #####################
  600. assign_source_group(${lib_sources})
  601. assign_source_group(${internal_headers})
  602. assign_source_group(${exported_headers})
  603. assign_source_group(${default_plugin_sources})
  604. assign_source_group(${ua_architecture_sources})
  605. if(UA_ENABLE_AMALGAMATION)
  606. add_library(open62541-object OBJECT ${PROJECT_BINARY_DIR}/open62541.c ${PROJECT_BINARY_DIR}/open62541.h)
  607. target_include_directories(open62541-object PRIVATE ${PROJECT_BINARY_DIR})
  608. # make sure the open62541_amalgamation target builds before so that amalgamation is finished and it is not executed again for open62541-object
  609. # and thus may overwrite the amalgamation result during multiprocessor compilation
  610. # the header is already a dependency of open62541 target itself
  611. add_dependencies(open62541-object
  612. open62541-amalgamation-header
  613. open62541-generator-types
  614. open62541-generator-transport
  615. open62541-generator-statuscode
  616. open62541-amalgamation-source)
  617. add_library(open62541 $<TARGET_OBJECTS:open62541-object>)
  618. if(UA_COMPILE_AS_CXX)
  619. set_source_files_properties(${PROJECT_BINARY_DIR}/open62541.c PROPERTIES LANGUAGE CXX)
  620. endif()
  621. else()
  622. add_definitions(-DUA_NO_AMALGAMATION)
  623. add_library(open62541-object OBJECT ${lib_sources} ${internal_headers} ${exported_headers})
  624. add_dependencies(open62541-object
  625. open62541-amalgamation-header
  626. open62541-generator-types
  627. open62541-generator-transport
  628. open62541-generator-statuscode)
  629. target_include_directories(open62541-object PRIVATE ${PROJECT_SOURCE_DIR}/src)
  630. add_library(open62541-plugins OBJECT ${default_plugin_sources} ${ua_architecture_sources} ${exported_headers})
  631. add_dependencies(open62541-plugins open62541-generator-types open62541-generator-transport)
  632. target_include_directories(open62541-plugins PRIVATE ${PROJECT_SOURCE_DIR}/plugins)
  633. target_include_directories(open62541-plugins PRIVATE ${PROJECT_BINARY_DIR}/src_generated)
  634. target_compile_definitions(open62541-plugins PRIVATE -DUA_DYNAMIC_LINKING_EXPORT)
  635. set_target_properties(open62541-plugins PROPERTIES FOLDER "open62541/lib")
  636. add_library(open62541 $<TARGET_OBJECTS:open62541-object> $<TARGET_OBJECTS:open62541-plugins>)
  637. if(UA_COMPILE_AS_CXX)
  638. set_source_files_properties(${lib_sources} PROPERTIES LANGUAGE CXX)
  639. set_source_files_properties(${default_plugin_sources} ${ua_architecture_sources} PROPERTIES LANGUAGE CXX)
  640. endif()
  641. endif()
  642. add_dependencies(open62541-amalgamation-source open62541-generator-namespace)
  643. add_dependencies(open62541-amalgamation-header open62541-generator-namespace)
  644. if(NOT UA_ENABLE_AMALGAMATION)
  645. add_dependencies(open62541-object open62541-generator-namespace)
  646. endif()
  647. # Export Symbols
  648. target_compile_definitions(open62541-object PRIVATE -DUA_DYNAMIC_LINKING_EXPORT)
  649. target_compile_definitions(open62541 PRIVATE -DUA_DYNAMIC_LINKING_EXPORT)
  650. if (UA_ENABLE_DISCOVERY_MULTICAST)
  651. target_compile_definitions(open62541-object PRIVATE -DMDNSD_DYNAMIC_LINKING_EXPORT)
  652. target_compile_definitions(open62541 PRIVATE -DMDNSD_DYNAMIC_LINKING_EXPORT)
  653. endif()
  654. # DLL requires linking to dependencies
  655. target_link_libraries(open62541 ${open62541_LIBRARIES})
  656. # Generate properly versioned shared library links on Linux
  657. SET_TARGET_PROPERTIES(open62541 PROPERTIES SOVERSION 0 VERSION "${OPEN62541_VER_MAJOR}.${OPEN62541_VER_MINOR}.${OPEN62541_VER_PATCH}")
  658. ##########################
  659. # Build Selected Targets #
  660. ##########################
  661. # always include, builds with make doc
  662. add_subdirectory(doc)
  663. if(UA_BUILD_EXAMPLES)
  664. add_subdirectory(examples)
  665. endif()
  666. if(UA_BUILD_UNIT_TESTS)
  667. if(UA_ENABLE_AMALGAMATION)
  668. # Cannot compile tests with amalgamation. Amalgamation uses the default plugins, not the testing plugins
  669. message(FATAL_ERROR "Unit tests cannot be generated with source amalgamation enabled")
  670. endif()
  671. enable_testing()
  672. add_subdirectory(tests)
  673. endif()
  674. if(UA_BUILD_FUZZING OR UA_BUILD_OSS_FUZZ OR UA_BUILD_FUZZING_CORPUS)
  675. add_subdirectory(tests/fuzz)
  676. endif()
  677. ############################
  678. # Linting run (clang-tidy) #
  679. ############################
  680. find_package(ClangTools)
  681. add_custom_target(lint ${CLANG_TIDY_PROGRAM}
  682. ${lib_sources}
  683. -checks=cert-*,performance-*,readability-*,-readability-braces-around-statements
  684. -warnings-as-errors=cert-*,performance-*,readability-*,-readability-braces-around-statements
  685. --
  686. -std=c99
  687. -I${PROJECT_SOURCE_DIR}/include
  688. -I${PROJECT_SOURCE_DIR}/plugins
  689. -I${PROJECT_SOURCE_DIR}/deps
  690. -I${PROJECT_SOURCE_DIR}/src
  691. -I${PROJECT_SOURCE_DIR}/src/server
  692. -I${PROJECT_SOURCE_DIR}/src/client
  693. -I${PROJECT_BINARY_DIR}/src_generated
  694. -DUA_NO_AMALGAMATION
  695. DEPENDS ${lib_sources}
  696. COMMENT "Run clang-tidy on the library")
  697. add_dependencies(lint open62541)
  698. add_custom_target(cpplint cpplint
  699. ${lib_sources}
  700. ${internal_headers}
  701. ${default_plugin_headers}
  702. ${default_plugin_sources}
  703. ${ua_architecture_headers}
  704. ${ua_architecture_sources}
  705. DEPENDS ${lib_sources}
  706. ${internal_headers}
  707. ${default_plugin_headers}
  708. ${default_plugin_sources}
  709. ${ua_architecture_headers}
  710. ${ua_architecture_sources}
  711. COMMENT "Run cpplint code style checker on the library")
  712. ##########################
  713. # Installation #
  714. ##########################
  715. # invoke via `make install`
  716. # specify install location with `-DCMAKE_INSTALL_PREFIX=xyz`
  717. # Enable shared library with `-DBUILD_SHARED_LIBS=ON`
  718. set(cmake_configfile_install ${LIB_INSTALL_DIR}/cmake)
  719. set(target_install_dest_name "${cmake_configfile_install}/open62541Targets.cmake")
  720. set(open62541_tools_dir share/open62541/tools)
  721. set(open62541_deps_dir include/open62541/deps)
  722. # export library (either static or shared depending on BUILD_SHARED_LIBS)
  723. install(TARGETS open62541
  724. EXPORT open62541Targets
  725. LIBRARY DESTINATION ${LIB_INSTALL_DIR}
  726. ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
  727. RUNTIME DESTINATION ${CMAKE_INSTALL_PREFIX}
  728. INCLUDES DESTINATION include/open62541 ${open62541_deps_dir})
  729. include(CMakePackageConfigHelpers)
  730. configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/tools/cmake/open62541-config.cmake.in"
  731. "${CMAKE_CURRENT_BINARY_DIR}/cmake/open62541-config.cmake"
  732. INSTALL_DESTINATION "${cmake_configfile_install}"
  733. PATH_VARS target_install_dest_name open62541_tools_dir)
  734. set(open62541_VERSION)
  735. get_target_property(open62541_VERSION open62541 VERSION)
  736. write_basic_package_version_file("${CMAKE_CURRENT_BINARY_DIR}/open62541ConfigVersion.cmake"
  737. VERSION ${open62541_VERSION}
  738. COMPATIBILITY AnyNewerVersion)
  739. install(EXPORT open62541Targets
  740. FILE open62541Targets.cmake
  741. DESTINATION "${cmake_configfile_install}")
  742. install(FILES "${CMAKE_CURRENT_BINARY_DIR}/cmake/open62541-config.cmake"
  743. "${CMAKE_CURRENT_BINARY_DIR}/open62541ConfigVersion.cmake"
  744. DESTINATION "${cmake_configfile_install}")
  745. if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
  746. install(FILES "${PROJECT_BINARY_DIR}/src_generated/open62541.pc"
  747. DESTINATION ${LIB_INSTALL_DIR}/pkgconfig)
  748. endif()
  749. # export amalgamated header open62541.h which is generated due to build of open62541-object
  750. if(UA_ENABLE_AMALGAMATION)
  751. install(FILES ${PROJECT_BINARY_DIR}/open62541.h DESTINATION include/open62541)
  752. endif()
  753. install(DIRECTORY deps/ DESTINATION ${open62541_deps_dir})
  754. install(DIRECTORY tools/ DESTINATION ${open62541_tools_dir} USE_SOURCE_PERMISSIONS)
  755. ##########################
  756. # Packaging (DEB/RPM) #
  757. ##########################
  758. # invoke via `make package`
  759. set(CPACK_GENERATOR "TGZ;DEB;RPM")
  760. set(CPACK_PACKAGE_VENDOR "open62541 team")
  761. set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "OPC UA implementation")
  762. set(CPACK_PACKAGE_DESCRIPTION "open62541 is a C-based library (linking with C++ projects is possible) with all necessary tools to implement dedicated OPC UA clients and servers, or to integrate OPC UA-based communication into existing applications.")
  763. set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
  764. set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE")
  765. set(CPACK_PACKAGE_VERSION_MAJOR "0")
  766. set(CPACK_PACKAGE_VERSION_MINOR "2")
  767. set(CPACK_PACKAGE_VERSION_PATCH "0")
  768. set(CPACK_DEBIAN_PACKAGE_MAINTAINER "open62541 team") #required
  769. include(CPack)
  770. ##################################
  771. # Visual studio solution folders #
  772. ##################################
  773. set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  774. set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "_CmakePredifinedTargets")
  775. set_target_properties(open62541 PROPERTIES FOLDER "open62541/lib")
  776. set_target_properties(open62541-object PROPERTIES FOLDER "open62541/lib")
  777. set_target_properties(lint PROPERTIES FOLDER "CodeAnalysis")
  778. set_target_properties(open62541-amalgamation-header PROPERTIES FOLDER "open62541/lib")
  779. set_target_properties(open62541-amalgamation-source PROPERTIES FOLDER "open62541/lib")
  780. set_target_properties(open62541-generator-namespace PROPERTIES FOLDER "open62541/generators")
  781. set_target_properties(open62541-generator-statuscode PROPERTIES FOLDER "open62541/generators")
  782. set_target_properties(open62541-generator-transport PROPERTIES FOLDER "open62541/generators")
  783. set_target_properties(open62541-generator-types PROPERTIES FOLDER "open62541/generators")
  784. ##################################
  785. # Architectures changes #
  786. ##################################
  787. GET_PROPERTY(ua_architecture_add_definitions GLOBAL PROPERTY UA_ARCHITECTURE_ADD_DEFINITIONS)
  788. add_definitions(${ua_architecture_add_definitions})
  789. GET_PROPERTY(ua_architecture_remove_definitions GLOBAL PROPERTY UA_ARCHITECTURE_REMOVE_DEFINITIONS)
  790. remove_definitions(${ua_architecture_remove_definitions})
  791. GET_PROPERTY(ua_architecture_append_to_library GLOBAL PROPERTY UA_ARCHITECTURE_APPEND_TO_LIBRARY)
  792. list(APPEND open62541_LIBRARIES ${ua_architecture_append_to_library})