macros_public.cmake 23 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522
  1. # --------------- Generate NodeIDs header ---------------------
  2. #
  3. # Generates header file from .csv which contains defines for every
  4. # node id to be used instead of numeric node ids.
  5. #
  6. # The resulting files will be put into OUTPUT_DIR with the names:
  7. # - NAME.h
  8. #
  9. #
  10. # The following arguments are accepted:
  11. # Options:
  12. #
  13. # Arguments taking one value:
  14. #
  15. # NAME Full name of the generated files, e.g. di_nodeids
  16. # TARGET_SUFFIX Suffix for the resulting target. e.g. ids-di
  17. # [TARGET_PREFIX] Optional prefix for the resulting target. Default `open62541-generator`
  18. # ID_PREFIX Prefix for the generated node ID defines, e.g. NS_DI
  19. # [OUTPUT_DIR] Optional target directory for the generated files. Default is '${PROJECT_BINARY_DIR}/src_generated'
  20. # FILE_CSV Path to the .csv file containing the node ids, e.g. 'OpcUaDiModel.csv'
  21. #
  22. function(ua_generate_nodeid_header)
  23. set(options )
  24. set(oneValueArgs NAME ID_PREFIX OUTPUT_DIR FILE_CSV TARGET_SUFFIX TARGET_PREFIX)
  25. set(multiValueArgs )
  26. cmake_parse_arguments(UA_GEN_ID "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN} )
  27. if(NOT UA_GEN_ID_TARGET_SUFFIX OR "${UA_GEN_ID_TARGET_SUFFIX}" STREQUAL "")
  28. message(FATAL_ERROR "ua_generate_nodeid_header function requires a value for the TARGET_SUFFIX argument")
  29. endif()
  30. # Set default value for output dir
  31. if(NOT UA_GEN_ID_OUTPUT_DIR OR "${UA_GEN_ID_OUTPUT_DIR}" STREQUAL "")
  32. set(UA_GEN_ID_OUTPUT_DIR ${PROJECT_BINARY_DIR}/src_generated)
  33. endif()
  34. # Set default target prefix
  35. if(NOT UA_GEN_ID_TARGET_PREFIX OR "${UA_GEN_ID_TARGET_PREFIX}" STREQUAL "")
  36. set(UA_GEN_ID_TARGET_PREFIX "open62541-generator")
  37. endif()
  38. add_custom_target(${UA_GEN_ID_TARGET_PREFIX}-${UA_GEN_ID_TARGET_SUFFIX} DEPENDS
  39. ${UA_GEN_ID_OUTPUT_DIR}/${UA_GEN_ID_NAME}.h
  40. )
  41. # Make sure that the output directory exists
  42. if(NOT EXISTS ${UA_GEN_ID_OUTPUT_DIR})
  43. file(MAKE_DIRECTORY ${UA_GEN_ID_OUTPUT_DIR})
  44. endif()
  45. # Header containing defines for all NodeIds
  46. add_custom_command(OUTPUT ${UA_GEN_ID_OUTPUT_DIR}/${UA_GEN_ID_NAME}.h
  47. PRE_BUILD
  48. COMMAND ${PYTHON_EXECUTABLE} ${open62541_TOOLS_DIR}/generate_nodeid_header.py
  49. ${UA_GEN_ID_FILE_CSV} ${UA_GEN_ID_OUTPUT_DIR}/${UA_GEN_ID_NAME} ${UA_GEN_ID_ID_PREFIX}
  50. DEPENDS ${open62541_TOOLS_DIR}/generate_nodeid_header.py
  51. ${UA_GEN_ID_FILE_CSV})
  52. endfunction()
  53. # --------------- Generate Datatypes ---------------------
  54. #
  55. # Generates Datatype definition based on the .csv and .bsd files of a nodeset.
  56. # The result of the generation will be C Code which can be compiled with the rest of the stack.
  57. # Some nodesets come with custom datatypes. These datatype structures first need to be
  58. # generated so that the nodeset can use these types.
  59. #
  60. # The resulting files will be put into OUTPUT_DIR with the names:
  61. # - NAME_generated.c
  62. # - NAME_generated.h
  63. # - NAME_generated_encoding_binary.h
  64. # - NAME_generated_handling.h
  65. #
  66. # The cmake resulting cmake target will be named like this:
  67. # open62541-generator-${TARGET_SUFFIX}
  68. #
  69. # The following arguments are accepted:
  70. # Options:
  71. #
  72. # [BUILTIN] Optional argument. If given, then builtin types will be generated.
  73. #
  74. # Arguments taking one value:
  75. #
  76. # NAME Full name of the generated files, e.g. ua_types_di
  77. # TARGET_SUFFIX Suffix for the resulting target. e.g. types-di
  78. # [TARGET_PREFIX] Optional prefix for the resulting target. Default `open62541-generator`
  79. # NAMESPACE_IDX Namespace index of the nodeset, when it is loaded into the server. This index
  80. # is used for the node ids withing the types array and is currently not determined automatically.
  81. # Make sure that it matches the namespace index in the server.
  82. # [OUTPUT_DIR] Optional target directory for the generated files. Default is '${PROJECT_BINARY_DIR}/src_generated'
  83. # FILE_CSV Path to the .csv file containing the node ids, e.g. 'OpcUaDiModel.csv'
  84. #
  85. # Arguments taking multiple values:
  86. #
  87. # FILES_BSD Path to the .bsd file containing the type definitions, e.g. 'Opc.Ua.Di.Types.bsd'. Multiple files can be
  88. # passed which will all combined to one resulting code.
  89. # [FILES_SELECTED] Optional path to a simple text file which contains a list of types which should be included in the generation.
  90. # The file should contain one type per line. Multiple files can be passed to this argument.
  91. #
  92. #
  93. function(ua_generate_datatypes)
  94. set(options BUILTIN)
  95. set(oneValueArgs NAME TARGET_SUFFIX TARGET_PREFIX NAMESPACE_IDX OUTPUT_DIR FILE_CSV)
  96. set(multiValueArgs FILES_BSD FILES_SELECTED)
  97. cmake_parse_arguments(UA_GEN_DT "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN} )
  98. if(NOT DEFINED open62541_TOOLS_DIR)
  99. message(FATAL_ERROR "open62541_TOOLS_DIR must point to the open62541 tools directory")
  100. endif()
  101. # ------ Argument checking -----
  102. if(NOT DEFINED UA_GEN_DT_NAMESPACE_IDX AND NOT "${UA_GEN_DT_NAMESPACE_IDX}" STREQUAL "0")
  103. message(FATAL_ERROR "ua_generate_datatype function requires a value for the NAMESPACE_IDX argument")
  104. endif()
  105. if(NOT UA_GEN_DT_NAME OR "${UA_GEN_DT_NAME}" STREQUAL "")
  106. message(FATAL_ERROR "ua_generate_datatype function requires a value for the NAME argument")
  107. endif()
  108. if(NOT UA_GEN_DT_TARGET_SUFFIX OR "${UA_GEN_DT_TARGET_SUFFIX}" STREQUAL "")
  109. message(FATAL_ERROR "ua_generate_datatype function requires a value for the TARGET_SUFFIX argument")
  110. endif()
  111. if(NOT UA_GEN_DT_FILE_CSV OR "${UA_GEN_DT_FILE_CSV}" STREQUAL "")
  112. message(FATAL_ERROR "ua_generate_datatype function requires a value for the FILE_CSV argument")
  113. endif()
  114. if(NOT UA_GEN_DT_FILES_BSD OR "${UA_GEN_DT_FILES_BSD}" STREQUAL "")
  115. message(FATAL_ERROR "ua_generate_datatype function requires a value for the FILES_BSD argument")
  116. endif()
  117. # Set default value for output dir
  118. if(NOT UA_GEN_DT_OUTPUT_DIR OR "${UA_GEN_DT_OUTPUT_DIR}" STREQUAL "")
  119. set(UA_GEN_DT_OUTPUT_DIR ${PROJECT_BINARY_DIR}/src_generated)
  120. endif()
  121. # Set default target prefix
  122. if(NOT UA_GEN_DT_TARGET_PREFIX OR "${UA_GEN_DT_TARGET_PREFIX}" STREQUAL "")
  123. set(UA_GEN_DT_TARGET_PREFIX "open62541-generator")
  124. endif()
  125. # ------ Add custom command and target -----
  126. set(UA_GEN_DT_NO_BUILTIN "--no-builtin")
  127. if (UA_GEN_DT_BUILTIN)
  128. set(UA_GEN_DT_NO_BUILTIN "")
  129. endif()
  130. set(SELECTED_TYPES_TMP "")
  131. foreach(f ${UA_GEN_DT_FILES_SELECTED})
  132. set(SELECTED_TYPES_TMP ${SELECTED_TYPES_TMP} "--selected-types=${f}")
  133. endforeach()
  134. set(BSD_FILES_TMP "")
  135. foreach(f ${UA_GEN_DT_FILES_BSD})
  136. set(BSD_FILES_TMP ${BSD_FILES_TMP} "--type-bsd=${f}")
  137. endforeach()
  138. # Make sure that the output directory exists
  139. if(NOT EXISTS ${UA_GEN_DT_OUTPUT_DIR})
  140. file(MAKE_DIRECTORY ${UA_GEN_DT_OUTPUT_DIR})
  141. endif()
  142. add_custom_command(OUTPUT ${UA_GEN_DT_OUTPUT_DIR}/${UA_GEN_DT_NAME}_generated.c
  143. ${UA_GEN_DT_OUTPUT_DIR}/${UA_GEN_DT_NAME}_generated.h
  144. ${UA_GEN_DT_OUTPUT_DIR}/${UA_GEN_DT_NAME}_generated_handling.h
  145. ${UA_GEN_DT_OUTPUT_DIR}/${UA_GEN_DT_NAME}_generated_encoding_binary.h
  146. PRE_BUILD
  147. COMMAND ${PYTHON_EXECUTABLE} ${open62541_TOOLS_DIR}/generate_datatypes.py
  148. --namespace=${UA_GEN_DT_NAMESPACE_IDX}
  149. ${SELECTED_TYPES_TMP}
  150. ${BSD_FILES_TMP}
  151. --type-csv=${UA_GEN_DT_FILE_CSV}
  152. ${UA_GEN_DT_NO_BUILTIN}
  153. ${UA_GEN_DT_OUTPUT_DIR}/${UA_GEN_DT_NAME}
  154. DEPENDS ${open62541_TOOLS_DIR}/generate_datatypes.py
  155. ${UA_GEN_DT_FILES_BSD}
  156. ${UA_GEN_DT_FILE_CSV}
  157. ${UA_GEN_DT_FILES_SELECTED})
  158. add_custom_target(${UA_GEN_DT_TARGET_PREFIX}-${UA_GEN_DT_TARGET_SUFFIX} DEPENDS
  159. ${UA_GEN_DT_OUTPUT_DIR}/${UA_GEN_DT_NAME}_generated.c
  160. ${UA_GEN_DT_OUTPUT_DIR}/${UA_GEN_DT_NAME}_generated.h
  161. ${UA_GEN_DT_OUTPUT_DIR}/${UA_GEN_DT_NAME}_generated_handling.h
  162. ${UA_GEN_DT_OUTPUT_DIR}/${UA_GEN_DT_NAME}_generated_encoding_binary.h
  163. )
  164. string(TOUPPER "${UA_GEN_DT_NAME}" GEN_NAME_UPPER)
  165. set(${GEN_NAME_UPPER}_SOURCES "${UA_GEN_DT_OUTPUT_DIR}/${UA_GEN_DT_NAME}_generated.c" CACHE INTERNAL "${UA_GEN_DT_NAME} source files")
  166. set(${GEN_NAME_UPPER}_HEADERS "${UA_GEN_DT_OUTPUT_DIR}/${UA_GEN_DT_NAME}_generated.h;${UA_GEN_DT_OUTPUT_DIR}/${UA_GEN_DT_NAME}_generated_handling.h;${UA_GEN_DT_OUTPUT_DIR}/${UA_GEN_DT_NAME}_generated_encoding_binary.h"
  167. CACHE INTERNAL "${UA_GEN_DT_NAME} header files")
  168. if(UA_COMPILE_AS_CXX)
  169. set_source_files_properties(${UA_GEN_DT_OUTPUT_DIR}/${UA_GEN_DT_NAME}_generated.c PROPERTIES LANGUAGE CXX)
  170. endif()
  171. endfunction()
  172. # --------------- Generate Nodeset ---------------------
  173. #
  174. # Generates C code for the given NodeSet2.xml file.
  175. # This C code can be used to initialize the server.
  176. #
  177. # The resulting files will be put into OUTPUT_DIR with the names:
  178. # - ua_namespace_NAME.c
  179. # - ua_namespace_NAME.h
  180. #
  181. # The resulting cmake target will be named like this:
  182. # open62541-generator-ns-${NAME}
  183. #
  184. # The following arguments are accepted:
  185. # Options:
  186. #
  187. # [INTERNAL] Optional argument. If given, then the generated node set code will use internal headers.
  188. #
  189. # Arguments taking one value:
  190. #
  191. # NAME Name of the nodeset, e.g. 'di'
  192. # [TYPES_ARRAY] Optional name of the types array containing the custom datatypes of this node set.
  193. # [OUTPUT_DIR] Optional target directory for the generated files. Default is '${PROJECT_BINARY_DIR}/src_generated'
  194. # [ENCODE_BINARY_SIZE] Optional array size for binary encoding extension objects.
  195. # [IGNORE] Optional file containing a list of node ids which should be ignored. The file should have one id per line.
  196. # [TARGET_PREFIX] Optional prefix for the resulting target. Default `open62541-generator`
  197. #
  198. # Arguments taking multiple values:
  199. #
  200. # FILE Path to the NodeSet2.xml file. Multiple values can be passed. These nodesets will be combined into one output.
  201. # [DEPENDS_TYPES] Optional list of types array which match with the DEPENDS_NS node sets. e.g. 'UA_TYPES;UA_TYPES_DI'
  202. # [DEPENDS_NS] Optional list of NodeSet2.xml files which are a dependency of this node set.
  203. # [DEPENDS_TARGET] Optional list of CMake targets this nodeset depends on.
  204. #
  205. #
  206. function(ua_generate_nodeset)
  207. set(options INTERNAL )
  208. set(oneValueArgs NAME TYPES_ARRAY OUTPUT_DIR ENCODE_BINARY_SIZE IGNORE TARGET_PREFIX)
  209. set(multiValueArgs FILE DEPENDS_TYPES DEPENDS_NS DEPENDS_TARGET)
  210. cmake_parse_arguments(UA_GEN_NS "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN} )
  211. if(NOT DEFINED open62541_TOOLS_DIR)
  212. message(FATAL_ERROR "open62541_TOOLS_DIR must point to the open62541 tools directory")
  213. endif()
  214. # ------ Argument checking -----
  215. if(NOT UA_GEN_NS_NAME OR "${UA_GEN_NS_NAME}" STREQUAL "")
  216. message(FATAL_ERROR "ua_generate_nodeset function requires a value for the NAME argument")
  217. endif()
  218. if(NOT UA_GEN_NS_FILE OR "${UA_GEN_NS_FILE}" STREQUAL "")
  219. message(FATAL_ERROR "ua_generate_nodeset function requires a value for the FILE argument")
  220. endif()
  221. # Set default value for output dir
  222. if(NOT UA_GEN_NS_OUTPUT_DIR OR "${UA_GEN_NS_OUTPUT_DIR}" STREQUAL "")
  223. set(UA_GEN_NS_OUTPUT_DIR ${PROJECT_BINARY_DIR}/src_generated)
  224. endif()
  225. # Set default target prefix
  226. if(NOT UA_GEN_NS_TARGET_PREFIX OR "${UA_GEN_NS_TARGET_PREFIX}" STREQUAL "")
  227. set(UA_GEN_NS_TARGET_PREFIX "open62541-generator")
  228. endif()
  229. # ------ Add custom command and target -----
  230. set(GEN_INTERNAL_HEADERS "")
  231. if (UA_GEN_NS_INTERNAL)
  232. set(GEN_INTERNAL_HEADERS "--internal-headers")
  233. endif()
  234. set(GEN_NS0 "")
  235. set(TARGET_SUFFIX "ns-${UA_GEN_NS_NAME}")
  236. set(FILE_SUFFIX "_${UA_GEN_NS_NAME}")
  237. string(REPLACE "-" "_" FILE_SUFFIX ${FILE_SUFFIX})
  238. if ("${UA_GEN_NS_NAME}" STREQUAL "ns0")
  239. set(GEN_NS0 "--generate-ns0")
  240. set(TARGET_SUFFIX "namespace")
  241. set(FILE_SUFFIX "0")
  242. endif()
  243. set(GEN_IGNORE "")
  244. if (UA_GEN_NS_IGNORE)
  245. set(GEN_IGNORE "--ignore=${UA_GEN_NS_IGNORE}")
  246. endif()
  247. set(GEN_BIN_SIZE "")
  248. if (UA_GEN_NS_ENCODE_BINARY_SIZE OR "${UA_GEN_NS_ENCODE_BINARY_SIZE}" STREQUAL "0")
  249. set(GEN_BIN_SIZE "--encode-binary-size=${UA_GEN_NS_ENCODE_BINARY_SIZE}")
  250. endif()
  251. set(TYPES_ARRAY_LIST "")
  252. foreach(f ${UA_GEN_NS_DEPENDS_TYPES})
  253. set(TYPES_ARRAY_LIST ${TYPES_ARRAY_LIST} "--types-array=${f}")
  254. endforeach()
  255. if(UA_GEN_NS_TYPES_ARRAY)
  256. set(TYPES_ARRAY_LIST ${TYPES_ARRAY_LIST} "--types-array=${UA_GEN_NS_TYPES_ARRAY}")
  257. endif()
  258. set(DEPENDS_FILE_LIST "")
  259. foreach(f ${UA_GEN_NS_DEPENDS_NS})
  260. set(DEPENDS_FILE_LIST ${DEPENDS_FILE_LIST} "--existing=${f}")
  261. endforeach()
  262. set(FILE_LIST "")
  263. foreach(f ${UA_GEN_NS_FILE})
  264. set(FILE_LIST ${FILE_LIST} "--xml=${f}")
  265. endforeach()
  266. # Make sure that the output directory exists
  267. if(NOT EXISTS ${UA_GEN_NS_OUTPUT_DIR})
  268. file(MAKE_DIRECTORY ${UA_GEN_NS_OUTPUT_DIR})
  269. endif()
  270. add_custom_command(OUTPUT ${UA_GEN_NS_OUTPUT_DIR}/ua_namespace${FILE_SUFFIX}.c
  271. ${UA_GEN_NS_OUTPUT_DIR}/ua_namespace${FILE_SUFFIX}.h
  272. PRE_BUILD
  273. COMMAND ${PYTHON_EXECUTABLE} ${open62541_TOOLS_DIR}/nodeset_compiler/nodeset_compiler.py
  274. ${GEN_INTERNAL_HEADERS}
  275. ${GEN_NS0}
  276. ${GEN_BIN_SIZE}
  277. ${GEN_IGNORE}
  278. ${TYPES_ARRAY_LIST}
  279. ${DEPENDS_FILE_LIST}
  280. ${FILE_LIST}
  281. ${UA_GEN_NS_OUTPUT_DIR}/ua_namespace${FILE_SUFFIX}
  282. DEPENDS
  283. ${open62541_TOOLS_DIR}/nodeset_compiler/nodeset_compiler.py
  284. ${open62541_TOOLS_DIR}/nodeset_compiler/nodes.py
  285. ${open62541_TOOLS_DIR}/nodeset_compiler/nodeset.py
  286. ${open62541_TOOLS_DIR}/nodeset_compiler/datatypes.py
  287. ${open62541_TOOLS_DIR}/nodeset_compiler/backend_open62541.py
  288. ${open62541_TOOLS_DIR}/nodeset_compiler/backend_open62541_nodes.py
  289. ${open62541_TOOLS_DIR}/nodeset_compiler/backend_open62541_datatypes.py
  290. ${UA_GEN_NS_FILE}
  291. ${UA_GEN_NS_DEPENDS_NS}
  292. )
  293. add_custom_target(${UA_GEN_NS_TARGET_PREFIX}-${TARGET_SUFFIX}
  294. DEPENDS
  295. ${UA_GEN_NS_OUTPUT_DIR}/ua_namespace${FILE_SUFFIX}.c
  296. ${UA_GEN_NS_OUTPUT_DIR}/ua_namespace${FILE_SUFFIX}.h)
  297. if (UA_GEN_NS_DEPENDS_TARGET)
  298. add_dependencies(${UA_GEN_NS_TARGET_PREFIX}-${TARGET_SUFFIX} ${UA_GEN_NS_DEPENDS_TARGET})
  299. endif()
  300. if(UA_COMPILE_AS_CXX)
  301. set_source_files_properties(${UA_GEN_NS_OUTPUT_DIR}/ua_namespace${FILE_SUFFIX}.c PROPERTIES LANGUAGE CXX)
  302. endif()
  303. set_property(GLOBAL PROPERTY "UA_GEN_NS_DEPENDS_FILE_${UA_GEN_NS_NAME}" ${UA_GEN_NS_DEPENDS_NS} ${UA_GEN_NS_FILE})
  304. set_property(GLOBAL PROPERTY "UA_GEN_NS_DEPENDS_TYPES_${UA_GEN_NS_NAME}" ${UA_GEN_NS_DEPENDS_TYPES} ${UA_GEN_NS_TYPES_ARRAY})
  305. string(TOUPPER "${UA_GEN_NS_NAME}" GEN_NAME_UPPER)
  306. set(UA_NODESET_${GEN_NAME_UPPER}_SOURCES "${UA_GEN_NS_OUTPUT_DIR}/ua_namespace${FILE_SUFFIX}.c" CACHE INTERNAL "UA_NODESET_${GEN_NAME_UPPER} source files")
  307. set(UA_NODESET_${GEN_NAME_UPPER}_HEADERS "${UA_GEN_NS_OUTPUT_DIR}/ua_namespace${FILE_SUFFIX}.h" CACHE INTERNAL "UA_NODESET_${GEN_NAME_UPPER} header files")
  308. set(UA_NODESET_${GEN_NAME_UPPER}_TARGET "${UA_GEN_NS_TARGET_PREFIX}-${TARGET_SUFFIX}" CACHE INTERNAL "UA_NODESET_${GEN_NAME_UPPER} target")
  309. endfunction()
  310. # --------------- Generate Nodeset and Datatypes ---------------------
  311. #
  312. # Generates C code for the given NodeSet2.xml and Datatype file.
  313. # This C code can be used to initialize the server.
  314. #
  315. # This is a combination of the ua_generate_datatypes, ua_generate_nodeset, and
  316. # ua_generate_nodeid_header macros.
  317. # This function can also be used to just create a nodeset without datatypes by
  318. # omitting the CSV, BSD, and NAMESPACE_IDX parameter.
  319. # If only one of the previous parameters is given, all of them are required.
  320. #
  321. # It is possible to define dependencies of nodesets by using the DEPENDS argument.
  322. # E.g. the PLCOpen nodeset depends on the 'di' nodeset. Thus it is enough to just
  323. # pass 'DEPENDS di' to the function. The 'di' nodeset then first needs to be generated
  324. # with this function or with the ua_generate_nodeset function.
  325. #
  326. # The resulting cmake target will be named like this:
  327. # open62541-generator-ns-${NAME}
  328. #
  329. # The following arguments are accepted:
  330. #
  331. # Options:
  332. #
  333. # INTERNAL Include internal headers. Required if custom datatypes are added.
  334. #
  335. # Arguments taking one value:
  336. #
  337. # NAME Short name of the nodeset. E.g. 'di'
  338. # FILE_NS Path to the NodeSet2.xml file. Multiple values can be passed. These nodesets will be combined into one output.
  339. #
  340. # [FILE_CSV] Optional path to the .csv file containing the node ids, e.g. 'OpcUaDiModel.csv'
  341. # [FILE_BSD] Optional path to the .bsd file containing the type definitions, e.g. 'Opc.Ua.Di.Types.bsd'. Multiple files can be
  342. # passed which will all combined to one resulting code.
  343. # [NAMESPACE_IDX] Optional namespace index of the nodeset, when it is loaded into the server. This parameter is mandatory if FILE_CSV
  344. # or FILE_BSD is set. See ua_generate_datatypes function.
  345. # [TARGET_PREFIX] Optional prefix for the resulting targets. Default `open62541-generator`
  346. #
  347. # Arguments taking multiple values:
  348. # [DEPENDS] Optional list of nodeset names on which this nodeset depends. These names must match any name from a previous
  349. # call to this funtion. E.g. 'di' if you are generating the 'plcopen' nodeset
  350. #
  351. #
  352. function(ua_generate_nodeset_and_datatypes)
  353. set(options INTERNAL)
  354. set(oneValueArgs NAME FILE_NS FILE_CSV FILE_BSD NAMESPACE_IDX OUTPUT_DIR TARGET_PREFIX)
  355. set(multiValueArgs DEPENDS)
  356. cmake_parse_arguments(UA_GEN "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN} )
  357. if(NOT DEFINED open62541_TOOLS_DIR)
  358. message(FATAL_ERROR "open62541_TOOLS_DIR must point to the open62541 tools directory")
  359. endif()
  360. if(NOT DEFINED open62541_NODESET_DIR)
  361. message(FATAL_ERROR "open62541_NODESET_DIR must point to the open62541/deps/ua-nodeset directory")
  362. endif()
  363. # ------ Argument checking -----
  364. if(NOT UA_GEN_NAME OR "${UA_GEN_NAME}" STREQUAL "")
  365. message(FATAL_ERROR "ua_generate_nodeset_and_datatypes function requires a value for the NAME argument")
  366. endif()
  367. string(TOUPPER "${UA_GEN_NAME}" GEN_NAME_UPPER)
  368. if(NOT UA_GEN_FILE_NS OR "${UA_GEN_FILE_NS}" STREQUAL "")
  369. message(FATAL_ERROR "ua_generate_nodeset_and_datatypes function requires a value for the FILE_NS argument")
  370. endif()
  371. if((NOT UA_GEN_FILE_CSV OR "${UA_GEN_FILE_CSV}" STREQUAL "") AND
  372. (NOT "${UA_GEN_FILE_BSD}" STREQUAL "" OR
  373. NOT "${UA_GEN_NAMESPACE_IDX}" STREQUAL ""))
  374. message(FATAL_ERROR "ua_generate_nodeset_and_datatypes function requires FILE_CSV argument if any of FILE_BSD or NAMESPACE_IDX are set")
  375. endif()
  376. if((NOT UA_GEN_FILE_BSD OR "${UA_GEN_FILE_BSD}" STREQUAL "") AND
  377. (NOT "${UA_GEN_FILE_CSV}" STREQUAL "" OR
  378. NOT "${UA_GEN_NAMESPACE_IDX}" STREQUAL ""))
  379. message(FATAL_ERROR "ua_generate_nodeset_and_datatypes function requires FILE_BSD argument if any of FILE_CSV or NAMESPACE_IDX are set")
  380. endif()
  381. if(NOT UA_GEN_NAMESPACE_IDX OR "${UA_GEN_NAMESPACE_IDX}" STREQUAL "" AND
  382. (NOT "${UA_GEN_FILE_CSV}" STREQUAL "" OR
  383. NOT "${UA_GEN_FILE_BSD}" STREQUAL ""))
  384. message(FATAL_ERROR "ua_generate_nodeset_and_datatypes function requires NAMESPACE_IDX argument if any of FILE_CSV or FILE_BSD are set")
  385. endif()
  386. # Set default value for output dir
  387. if(NOT UA_GEN_OUTPUT_DIR OR "${UA_GEN_OUTPUT_DIR}" STREQUAL "")
  388. set(UA_GEN_OUTPUT_DIR ${PROJECT_BINARY_DIR}/src_generated)
  389. endif()
  390. # Set default target prefix
  391. if(NOT UA_GEN_TARGET_PREFIX OR "${UA_GEN_TARGET_PREFIX}" STREQUAL "")
  392. set(UA_GEN_TARGET_PREFIX "open62541-generator")
  393. endif()
  394. set(NODESET_DEPENDS_TARGET "")
  395. set(NODESET_TYPES_ARRAY "UA_TYPES")
  396. if(NOT "${UA_GEN_FILE_BSD}" STREQUAL "")
  397. # Generate Datatypes for nodeset
  398. ua_generate_datatypes(
  399. NAME "ua_types_${UA_GEN_NAME}"
  400. TARGET_PREFIX "${UA_GEN_TARGET_PREFIX}"
  401. TARGET_SUFFIX "types-${UA_GEN_NAME}"
  402. NAMESPACE_IDX ${UA_GEN_NAMESPACE_IDX}
  403. FILE_CSV "${UA_GEN_FILE_CSV}"
  404. FILES_BSD "${UA_GEN_FILE_BSD}"
  405. OUTPUT_DIR "${UA_GEN_OUTPUT_DIR}"
  406. )
  407. set(NODESET_DEPENDS_TARGET "${UA_GEN_TARGET_PREFIX}-types-${UA_GEN_NAME}")
  408. set(NODESET_TYPES_ARRAY "UA_TYPES_${GEN_NAME_UPPER}")
  409. ua_generate_nodeid_header(
  410. NAME "${UA_GEN_NAME}_nodeids"
  411. ID_PREFIX "${GEN_NAME_UPPER}"
  412. FILE_CSV "${UA_GEN_FILE_CSV}"
  413. OUTPUT_DIR "${UA_GEN_OUTPUT_DIR}"
  414. TARGET_PREFIX "${UA_GEN_TARGET_PREFIX}"
  415. TARGET_SUFFIX "ids-${UA_GEN_NAME}"
  416. )
  417. set(NODESET_DEPENDS_TARGET ${NODESET_DEPENDS_TARGET} "${UA_GEN_TARGET_PREFIX}-ids-${UA_GEN_NAME}")
  418. endif()
  419. # Create a list of nodesets on which this nodeset depends on
  420. if (NOT UA_GEN_DEPENDS OR "${UA_GEN_DEPENDS}" STREQUAL "" )
  421. set(NODESET_DEPENDS "${open62541_NODESET_DIR}/Schema/Opc.Ua.NodeSet2.xml")
  422. set(TYPES_DEPENDS "UA_TYPES")
  423. else()
  424. foreach(f ${UA_GEN_DEPENDS})
  425. if(EXISTS ${f})
  426. set(NODESET_DEPENDS ${NODESET_DEPENDS} "${f}")
  427. else()
  428. get_property(DEPENDS_FILE GLOBAL PROPERTY "UA_GEN_NS_DEPENDS_FILE_${f}")
  429. if(NOT DEPENDS_FILE OR "${DEPENDS_FILE}" STREQUAL "")
  430. message(FATAL_ERROR "Nodeset dependency ${f} needs to be generated before ${UA_GEN_NAME}")
  431. endif()
  432. set(NODESET_DEPENDS ${NODESET_DEPENDS} "${DEPENDS_FILE}")
  433. get_property(DEPENDS_TYPES GLOBAL PROPERTY "UA_GEN_NS_DEPENDS_TYPES_${f}")
  434. set(TYPES_DEPENDS ${TYPES_DEPENDS} "${DEPENDS_TYPES}")
  435. set(NODESET_DEPENDS_TARGET ${NODESET_DEPENDS_TARGET} "${UA_GEN_TARGET_PREFIX}-ns-${f}")
  436. endif()
  437. endforeach()
  438. endif()
  439. set(NODESET_INTERNAL "")
  440. if (${UA_GEN_INTERNAL})
  441. set(NODESET_INTERNAL "INTERNAL")
  442. endif()
  443. ua_generate_nodeset(
  444. NAME "${UA_GEN_NAME}"
  445. FILE "${UA_GEN_FILE_NS}"
  446. TYPES_ARRAY "${NODESET_TYPES_ARRAY}"
  447. ${NODESET_INTERNAL}
  448. DEPENDS_TYPES ${TYPES_DEPENDS}
  449. DEPENDS_NS ${NODESET_DEPENDS}
  450. DEPENDS_TARGET ${NODESET_DEPENDS_TARGET}
  451. OUTPUT_DIR "${UA_GEN_OUTPUT_DIR}"
  452. TARGET_PREFIX "${UA_GEN_TARGET_PREFIX}"
  453. )
  454. endfunction()