CMakeLists.txt 9.5 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221
  1. cmake_minimum_required(VERSION 2.8.8)
  2. # set(CMAKE_VERBOSE_MAKEFILE on )
  3. project(open62541 C)
  4. set(open62541_VERSION_MAJOR 0)
  5. set(open62541_VERSION_MINOR 0)
  6. set(NVIM_VERSION_PATCH 0)
  7. set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/cmake")
  8. # Set default build type.
  9. if (NOT CMAKE_BUILD_TYPE)
  10. message(STATUS "CMAKE_BUILD_TYPE not given; setting to 'RelWithDebInfo'.")
  11. set(CMAKE_BUILD_TYPE "RelWithDebInfo" CACHE STRING "Choose the type of build." FORCE)
  12. endif()
  13. # compiler flags
  14. if(CMAKE_COMPILER_IS_GNUCC OR "${CMAKE_C_COMPILER_ID}" STREQUAL "Clang")
  15. add_definitions(-std=c99 -pipe -Wall -Wextra -Werror -Wformat
  16. -Wno-unused-parameter -Wno-unused-function -Wno-unused-label -Wpointer-arith -Wreturn-type -Wsign-compare -Wmultichar
  17. -Wshadow -Wcast-align -Wcast-qual -Wmissing-prototypes -Wstrict-prototypes # -Wconversion
  18. -Winit-self -Wuninitialized -Wno-deprecated -Wformat-security -ffunction-sections -fdata-sections)
  19. if(NOT "${CMAKE_C_COMPILER_ID}" STREQUAL "Clang")
  20. add_definitions(-Wformat-nonliteral)
  21. set (CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -Wl,--gc-sections")
  22. set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--gc-sections")
  23. else()
  24. add_definitions(-Wno-gnu-statement-expression)
  25. endif()
  26. if(NOT WIN32)
  27. add_definitions(-fstack-protector -fPIC -fvisibility=hidden)
  28. endif()
  29. endif()
  30. # main sources of libopen62541
  31. include_directories("${CMAKE_CURRENT_SOURCE_DIR}/include")
  32. include_directories("${CMAKE_CURRENT_SOURCE_DIR}/src")
  33. file(GLOB_RECURSE exported_headers "${CMAKE_CURRENT_SOURCE_DIR}/include/*.h")
  34. file(GLOB generated_headers "${PROJECT_BINARY_DIR}/src_generated/*.h")
  35. set(lib_sources src/ua_types.c
  36. src/ua_types_encoding_binary.c
  37. ${PROJECT_BINARY_DIR}/src_generated/ua_types_generated.c
  38. ${PROJECT_BINARY_DIR}/src_generated/ua_transport_generated.c
  39. ${PROJECT_BINARY_DIR}/src_generated/ua_nodeids.h
  40. src/ua_securechannel.c
  41. src/ua_session.c
  42. src/server/ua_server.c
  43. src/server/ua_server_addressspace.c
  44. src/server/ua_server_binary.c
  45. src/server/ua_nodes.c
  46. src/server/ua_server_worker.c
  47. src/server/ua_securechannel_manager.c
  48. src/server/ua_session_manager.c
  49. src/server/ua_services_discovery.c
  50. src/server/ua_services_securechannel.c
  51. src/server/ua_services_session.c
  52. src/server/ua_services_attribute.c
  53. src/server/ua_services_nodemanagement.c
  54. src/server/ua_services_view.c
  55. ${exported_headers}
  56. ${generated_headers} )
  57. ## multithreading
  58. option(MULTITHREADING "Enable multithreading" OFF)
  59. if(MULTITHREADING)
  60. set(UA_MULTITHREADING ON)
  61. find_package(Threads REQUIRED)
  62. list(APPEND lib_sources src/server/ua_nodestore_concurrent.c)
  63. else()
  64. list(APPEND lib_sources src/server/ua_nodestore.c)
  65. endif()
  66. ## set debug flag
  67. if(CMAKE_BUILD_TYPE MATCHES Debug)
  68. set(UA_DEBUG ON)
  69. else()
  70. set(UA_DEBUG OFF)
  71. endif()
  72. ## extensions
  73. option(EXTENSION_STATELESS "Enable stateless extension" OFF)
  74. option(EXTENSION_UDP "Enable udp extension" OFF)
  75. if(EXTENSION_UDP)
  76. set(EXTENSION_STATELESS ON)
  77. message(STATUS "Extensions: enabling udp")
  78. add_definitions(-DEXTENSION_UDP)
  79. endif()
  80. if(EXTENSION_STATELESS)
  81. message(STATUS "Extensions: enabling stateless")
  82. add_definitions(-DEXTENSION_STATELESS)
  83. add_executable(statelessClient $<TARGET_OBJECTS:open62541-objects> examples/statelessClient.c)
  84. if(MULTITHREADING)
  85. target_link_libraries(statelessClient urcu-cds urcu urcu-common pthread)
  86. endif()
  87. endif()
  88. ## self-signed certificates
  89. option(ENABLE_SELFSIGNED "Enable self-signed certificates" OFF)
  90. if(ENABLE_SELFSIGNED)
  91. message(STATUS "Enabling self-signed certificates")
  92. SET(lib_sources ${lib_sources} ${PROJECT_BINARY_DIR}/localhost.der ${PROJECT_BINARY_DIR}/ca.crt)
  93. add_custom_command(OUTPUT ${PROJECT_BINARY_DIR}/localhost.der
  94. ${PROJECT_BINARY_DIR}/ca.crt
  95. COMMAND python ${PROJECT_SOURCE_DIR}/tools/certs/create_self-signed.py ${PROJECT_BINARY_DIR}
  96. DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tools/certs/create_self-signed.py
  97. ${CMAKE_CURRENT_SOURCE_DIR}/tools/certs/localhost.cnf)
  98. endif()
  99. add_library(open62541-objects OBJECT ${lib_sources}) # static version that exports all symbols
  100. add_library(open62541 SHARED $<TARGET_OBJECTS:open62541-objects>)
  101. target_compile_definitions(open62541-objects PUBLIC UA_DYNAMIC_LINKING)
  102. ## logging
  103. set(UA_LOGLEVEL 400 CACHE STRING "Level at which logs shall be reported")
  104. ## coverage
  105. option(ENABLE_COVERAGE "Enable gcov coverage" OFF)
  106. if(ENABLE_COVERAGE)
  107. message(STATUS "Enabling gcov support")
  108. set(CMAKE_BUILD_TYPE DEBUG)
  109. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fprofile-arcs -ftest-coverage")
  110. set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
  111. set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
  112. endif()
  113. # set the precompiler flags
  114. configure_file("src/ua_config.h.in" "${PROJECT_BINARY_DIR}/src_generated/ua_config.h")
  115. # download queue.h if required
  116. if(WIN32)
  117. if(NOT EXISTS "${PROJECT_BINARY_DIR}/src_generated/queue.h")
  118. file(DOWNLOAD "http://openbsd.cs.toronto.edu/cgi-bin/cvsweb/~checkout~/src/sys/sys/queue.h" "${PROJECT_BINARY_DIR}/src_generated/queue.h" STATUS result)
  119. list(GET result 0 download_ok)
  120. if(NOT ${download_ok} MATCHES 0)
  121. file(REMOVE "${PROJECT_BINARY_DIR}/src_generated/queue.h") # remove empty file if created
  122. message(FATAL_ERROR "queue.h could not be downloaded")
  123. endif()
  124. endif()
  125. endif(WIN32)
  126. # generate code from xml definitions
  127. file(MAKE_DIRECTORY "${PROJECT_BINARY_DIR}/src_generated")
  128. include_directories("${PROJECT_BINARY_DIR}/src_generated")
  129. add_custom_command(OUTPUT ${PROJECT_BINARY_DIR}/src_generated/ua_types_generated.c
  130. ${PROJECT_BINARY_DIR}/src_generated/ua_types_generated.h
  131. PRE_BUILD
  132. COMMAND python ${PROJECT_SOURCE_DIR}/tools/generate_datatypes.py --typedescriptions ${PROJECT_SOURCE_DIR}/tools/schema/NodeIds.csv 0 ${PROJECT_SOURCE_DIR}/tools/schema/Opc.Ua.Types.bsd ${PROJECT_BINARY_DIR}/src_generated/ua_types
  133. DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tools/generate_datatypes.py
  134. ${CMAKE_CURRENT_SOURCE_DIR}/tools/schema/Opc.Ua.Types.bsd
  135. ${CMAKE_CURRENT_SOURCE_DIR}/tools/schema/NodeIds.csv)
  136. add_custom_command(OUTPUT ${PROJECT_BINARY_DIR}/src_generated/ua_transport_generated.c
  137. ${PROJECT_BINARY_DIR}/src_generated/ua_transport_generated.h
  138. PRE_BUILD
  139. COMMAND python ${PROJECT_SOURCE_DIR}/tools/generate_datatypes.py --ns0-types-xml ${PROJECT_SOURCE_DIR}/tools/schema/Opc.Ua.Types.bsd 1 ${PROJECT_SOURCE_DIR}/tools/schema/Custom.Opc.Ua.Transport.bsd ${PROJECT_BINARY_DIR}/src_generated/ua_transport
  140. DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tools/generate_datatypes.py
  141. ${CMAKE_CURRENT_SOURCE_DIR}/tools/schema/Custom.Opc.Ua.Transport.bsd)
  142. add_custom_command(OUTPUT ${PROJECT_BINARY_DIR}/src_generated/ua_nodeids.h
  143. PRE_BUILD
  144. COMMAND python ${PROJECT_SOURCE_DIR}/tools/generate_nodeids.py ${PROJECT_SOURCE_DIR}/tools/schema/NodeIds.csv ${PROJECT_BINARY_DIR}/src_generated/ua_nodeids
  145. DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tools/generate_nodeids.py
  146. ${CMAKE_CURRENT_SOURCE_DIR}/tools/schema/NodeIds.csv)
  147. # build example client
  148. option(CLIENT "Build a test client" OFF)
  149. if(CLIENT)
  150. message(STATUS "Extensions: enabling client")
  151. add_definitions( -DBENCHMARK=1 )
  152. # the client is built directly with the .o files as it currently uses
  153. # internal functions that are not exported to the shared lib.
  154. add_executable(exampleClient $<TARGET_OBJECTS:open62541-objects> examples/opcuaClient.c)
  155. if(MULTITHREADING)
  156. target_link_libraries(exampleClient urcu-cds urcu urcu-common pthread)
  157. endif()
  158. endif()
  159. # build example server
  160. option(EXAMPLESERVER "Build a test server" OFF)
  161. if(EXAMPLESERVER)
  162. set(server_sources examples/opcuaServer.c
  163. examples/networklayer_tcp.c
  164. examples/logger_stdout.c)
  165. if(EXTENSION_UDP)
  166. list(APPEND server_sources examples/networklayer_udp.c)
  167. endif()
  168. add_executable(exampleServer ${server_sources} ${exported_headers} ${generated_headers})
  169. target_link_libraries(exampleServer open62541)
  170. if(WIN32)
  171. target_link_libraries(exampleServer ws2_32)
  172. endif(WIN32)
  173. if(MULTITHREADING)
  174. target_link_libraries(exampleServer urcu-cds urcu urcu-common pthread)
  175. endif()
  176. endif()
  177. # build unit tests
  178. option(ENABLE_UNIT_TESTS "Run unit tests after building" OFF)
  179. if(ENABLE_UNIT_TESTS)
  180. enable_testing()
  181. add_subdirectory(tests)
  182. endif()
  183. # build documentation
  184. option(GENERATE_DOCUMENTATION "Generate doxygen documentation" OFF)
  185. if(GENERATE_DOCUMENTATION)
  186. find_package(Doxygen)
  187. if(NOT DOXYGEN_FOUND)
  188. message(FATAL_ERROR "Doxygen is not installed or not properly configured")
  189. endif(NOT DOXYGEN_FOUND)
  190. configure_file(${CMAKE_CURRENT_SOURCE_DIR}/doc/Doxyfile.in ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile @ONLY)
  191. add_custom_target(doc
  192. ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile
  193. WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
  194. COMMENT "Generating API documentation with Doxygen")
  195. endif()